Wie Sie Textdatei in Excel VBA lesen und aktualisiert

Question

Ich bin neu in Excel VBA. Ich mache ein Projekt mit Arduino und Gobetwino, um Sensoren Daten in eine Textdatei zu protokollieren. Um fortzufahren, muss ich ein Makro verwenden, um Daten aus der Textdatei nach Excel zu protokollieren und sie jedes Mal zu aktualisieren, wenn ich sie öffne oder das Makro ausführe.

11/28/2016 12:00:00 sensor triggered 
11/29/2016 00:00:05 sensor triggered 
11/29/2016 05:00:00 sensor triggered 

ich die neuesten Daten in erster Linie in Excel sehen muß: Zusätzlich Gobetwino wird mit Datum und Inhalt wie die folgenden Zeilen Daten in der Textdatei Zeile schreiben.

Kann mir jemand dabei helfen, VBA-Code zu schreiben?

Answer 1

Dies wird den Trick tun. Sie können es einer Schaltfläche oder einer Verknüpfung zuweisen - es aktualisiert Daten aus der Datei bei jedem Aufruf in umgekehrter Reihenfolge.

Sub reverseFile() 

    ' put the file into the same dir as spreasheet 
    Const FILE_NAME = "sensorData.txt" 

    Dim fileNum As Integer 
    Dim line As String 
    Dim c As New Collection 
    Dim a() As String 
    Dim i As Long 

    ' read file line-by-line 
    fileNum = FreeFile() 
    Open ThisWorkbook.Path & Application.PathSeparator _ 
      & FILE_NAME For Input As #fileNum 

    While Not EOF(fileNum) 
     Line Input #fileNum, line 
     c.Add line 
    Wend 

    Close #fileNum 

    ' reverse the input lines into array 
    ReDim a(1 To c.Count) 
    For i = LBound(a) To UBound(a): a(i) = c(c.Count - i + 1): Next i 

    ' display results in the spreadsheet 
    With Worksheets("Sheet1").[a1] 
     .CurrentRegion.Clear 
     .Resize(UBound(a), 1) = Application.Transpose(a) 
    End With 

End Sub