XSLT: Filter/Gruppenknoten in Variablen

Question

Ich versuche, Knoten in einer Variablen zu filtern/gruppieren.

XML:

<?xml version="1.0" encoding="UTF-8"?> 
<row> 
    <cell n="1"/> 
    <cell n="2"/> 
    <cell n="3"/> 
    <cell n="4"/> 
    <cell n="2"/> 
    <cell n="5"/> 
</row> 

XSLT 2:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="row"> 
     <xsl:element name="row"> 
      <xsl:apply-templates/> 
     </xsl:element> 
    </xsl:template> 

    <xsl:template match="cell"> 
     <xsl:variable name="attribute" select="@n"/> 
     <xsl:variable name="sequence"> 
      <xsl:call-template name="seq"> 
       <xsl:with-param name="attribute" select="$attribute"/> 
      </xsl:call-template> 
     </xsl:variable> 
     <xsl:for-each-group select="$sequence" group-by="cell/@val"> 
      <xsl:sequence select="."></xsl:sequence> 
     </xsl:for-each-group> 
    </xsl:template> 

    <xsl:template name="seq"> 
     <xsl:param name="attribute"/> 
     <xsl:element name="cell"> 
      <xsl:attribute name="val"> 
       <xsl:value-of select="$attribute"/> 
      </xsl:attribute> 
     </xsl:element> 
    </xsl:template> 

</xsl:stylesheet> 

Vorgesehen Ausgabe:

<?xml version="1.0" encoding="UTF-8"?> 
<row> 
    <cell val="1"/> 
    <cell val="2"/> 
    <cell val="3"/> 
    <cell val="4"/> 
    <cell val="5"/> 
</row> 

Der XML-Kodex ist nur ein Beispiel für eine viel kompliziertere Datei. Ich möchte zuerst alle Elemente cell bearbeiten und das Ergebnis in einer Variablen speichern. Im zweiten Lauf möchte ich die Knoten der Sequenz filtern oder neu gruppieren.

Ich habe auch versucht $sequence mit Prädikaten zu filtern:

<xsl:sequence select="$sequence/*[@val != preceding-sibling::cell/@val]"/> 

die Ausgabedatei leer In diesem Fall ist.

EDIT 2 (jetzt es funktioniert):

<?xml version="1.0" encoding="UTF-8"?> 

<xsl:template match="row"> 
    <xsl:variable name="sequence"> 
     <xsl:for-each select="cell"> 
      <xsl:variable name="attribute" select="@n"/> 
      <xsl:call-template name="seq"> 
       <xsl:with-param name="attribute" select="$attribute"/> 
      </xsl:call-template> 
     </xsl:for-each> 
    </xsl:variable> 
    <row> 
     <xsl:for-each-group group-by="@val" select="$sequence/*"> 
      <xsl:sequence select="."/> 
     </xsl:for-each-group> 
    </row> 
</xsl:template> 

<xsl:template name="seq"> 
    <xsl:param name="attribute"/> 
    <xsl:element name="cell"> 
     <xsl:attribute name="val"> 
      <xsl:value-of select="$attribute"/> 
     </xsl:attribute> 
    </xsl:element> 
</xsl:template> 

Answer 1

Hier ist ein XSLT 2.0 Sheet, das <cell n="x">...</cell> in <cell val="n">...</cell> zuerst und dann Gruppen sind solche Zellenelemente durch die Transformationen val Attribut zum Entfernen von Dubletten:

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

    <xsl:output indent="yes"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="row"> 
     <xsl:copy> 
      <xsl:variable name="transformed-cells"> 
       <xsl:apply-templates select="cell"/> 
      </xsl:variable> 
      <xsl:for-each-group select="$transformed-cells/cell" group-by="@val"> 
       <xsl:copy-of select="."/> 
      </xsl:for-each-group> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="cell/@n"> 
     <xsl:attribute name="val" select="."/> 
    </xsl:template> 

</xsl:transform> 

Ausgang ist

<row> 
    <cell val="1"/> 
    <cell val="2"/> 
    <cell val="3"/> 
    <cell val="4"/> 
    <cell val="5"/> 
</row> 

http://xsltransform.net/a9Giwz