Kopiere direkte Kinder und ihre Attribute nur in XSLT 1.0?

Question

XML-Input-:

<root> 
    <recordList> 
    <record priref="1"> 
     <Group attr="val"> 
     <Field1>Value X</Field1> 
     <Field2> 
      <value lang="en-US">Foo</value> 
      <value lang="de-DE">Bar</value> 
     </Field2> 
     </Group> 
     <Field3 attr="val">Value Y</Field3> 
    </record> 
    <record priref="2"> 
     <Field3 attr="val">Value Z</Field3> 
    </record> 
    </recordList> 
</root> 

gewünschte Ausgabe (eine Art "flache Kopie" nur mit den unmittelbar untergeordneten Elemente und Attribute):

<root> 
    <record priref="1"> 
    <Group attr="val" /> 
    <Field3 attr="val">Value Y</Field3> 
    </record> 
    <record priref="2"> 
    <Field3 attr="val">Value Z</Field3> 
    </record> 
</root> 

Gibt es eine andere Art und Weise (zB ohne for-each) um das zu erreichen?

<xsl:template match="/"> 
    <root> 
    <xsl:apply-templates select="root/recordList/record" /> 
    </root> 
</xsl:template> 

<xsl:template match="record"> 
    <xsl:copy> 
    <xsl:copy-of select="@*"/> 
    <xsl:for-each select="*"> 
     <xsl:copy> 
     <xsl:copy-of select="@* | text()"/> 
     </xsl:copy> 
    </xsl:for-each> 
    </xsl:copy> 
</xsl:template> 

edit: die Textknoten „Wert Y“ und „Wert Z“ sollte eigentlich im Ergebnis. "Foo" und "Bar" sind im Ergebnis immer noch nicht erwünscht.

Answer 1

Eine sehr kurze Vorlage verwendet die parent:: -Achse:

<xsl:template match="root|record|*[parent::record]|*[parent::record]/text()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*" /> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="text()" /> 

Es ist Ausgang

<?xml version="1.0"?> 
<root> 
    <record priref="1"> 
    <Group attr="val"> 
    </Group> 
    <Field3 attr="val">Value Y</Field3></record> 
    <record priref="2"> 
    <Field3 attr="val">Value Z</Field3> 
    </record> 
</root> 

Answer 2

Eine Möglichkeit ist, keine Enkelkinder verarbeiten:

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 

    <xsl:strip-space elements="*"/> 
    <xsl:output indent="yes"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="recordList"> 
     <xsl:apply-templates/> 
    </xsl:template> 

    <xsl:template match="record/*/node()"/> 
</xsl:transform> 

Answer 3

Wie wäre es einfach Schablonen nicht auf Knoten anwenden, die Sie nicht möchten?

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="recordList"> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="record/*"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|text()"/> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>