Wie kann ich die Wartezeit zwischen zwei Methoden, die auf die gleiche Datei zugreifen, loswerden?

Question

Ich habe den folgenden Teil des VBSCript-Codes, um einen Abschnitt (strSection) und ein Element in diesem Abschnitt (StrItem) in einer Nur-Text-Datei zu finden.

Do While Not myINIFile.AtEndOfStream 
    sl_Sleep(100) 
    s = myINIFile.ReadLine <--- **This is the line that rises the exception** 
    If s = strSection Then 
    'Find the correct line 
    Do While Not myINIFile.AtEndOfStream 
     s = myINIFile.ReadLine 
     If InStr(s, strItem)>0 Then 
     Exit Do 
     End if    
    Loop    
    Exit Do 
    End if    
Loop 

Es scheint, dass, wenn ich nicht die eingeschläfert (100) (Millisekunden) (oder niedrigere Werte verwenden wie 20 oder 50) ich schließlich eine Ausnahme erhalten, dass „Der Prozess sagt die Datei nicht, da ein anderer Prozess zugreifen hat einen Teil der Datei gesperrt ".

Ich denke, dass die Bedingung in der Do While die ReadLine-Methode aufgerufen wird, während der AtEndOfStream noch nicht beendet ist. Die Verwendung von 100 ms für jede Leitung verlangsamt jedoch den Prozess auf nicht akzeptable Geschwindigkeiten.

Ist das was wirklich passiert oder ist das Problem woanders? Gibt es etwas, was ich tun kann, um zu verhindern, dass dieser Prozess gesperrt wird oder ein wenig mehr wartet (bis es freigegeben wird) nur wenn es gesperrt ist, so dass es keine Ausnahme auslöst?

---

EDIT: Dieser Code Schleifen durch eine Datei, die wie folgt aussieht: angeblich durch die Datei gehen, wird

[Section1]  
param1 = 100  
param2 = 200  
param3 = 300  

[Section2]  
param1 = 1000  
param2 = 2000  
param3 = 3000 

[Section3]  
param1 = 1 
param2 = 2 
param3 = 5 
param4 = 10 
param5 = 20 

Der Code, bis er die [SectionX] Zeile (strSection) und dann halten findet Lesen von Zeilen, bis sie die Zeile "paramx" (strItem) findet. Diese Zeile wird dann in 's' gespeichert und später verarbeitet.

Answer 1

der Code, den Sie geschrieben haben, funktioniert perfekt für mich. Ich bekomme keine Ausnahme ...

greifen Sie auf die Datei woanders hin, während Sie Ihren gebuchten Code verwenden?

haben Sie versucht, die gesamte Datei zu lesen und dann die Zeichenfolge zu analysieren? siehe http://www.motobit.com/tips/detpg_asp-vbs-read-write-ini-files/

Answer 2

Funktion readini (myFilePath, mySection, myKey) 'Diese Funktion einen Wert aus einer INI-Datei lesen gibt ' 'Argumente: ' myFilePath [string] der (Pfad und Datei) Name der INI-Datei 'mySection [string] der Abschnitt in der zu durchsuchenden INI-Datei ' myKey [string] der Schlüssel, dessen Wert zurückgegeben werden soll ' ' der Wert [string] für den angegebenen Schlüssel im angegebenen Abschnitt '

Const ForReading = 1 
Const ForWriting = 2 
Const ForAppending = 8 

Dim intEqualPos 
Dim objFSO, objIniFile 
Dim strFilePath, strKey, strLeftString, strLine, strSection 

Set objFSO = CreateObject("Scripting.FileSystemObject") 

ReadIni  = "" 
strFilePath = Trim(myFilePath) 
strSection = Trim(mySection) 
strKey  = Trim(myKey) 

If objFSO.FileExists(strFilePath) Then 
    Set objIniFile = objFSO.OpenTextFile(strFilePath, ForReading, False) 
    Do While objIniFile.AtEndOfStream = False 
     strLine = Trim(objIniFile.ReadLine) 

     ' Check if section is found in the current line 
     If LCase(strLine) = "[" & LCase(strSection) & "]" Then 
      strLine = Trim(objIniFile.ReadLine) 

      ' Parse lines until the next section is reached 
      Do While Left(strLine, 1) <> "[" 
       ' Find position of equal sign in the line 
       intEqualPos = InStr(1, strLine, "=", 1) 
       If intEqualPos > 0 Then 
        strLeftString = Trim(Left(strLine, intEqualPos - 1)) 
        ' Check if item is found in the current line 
        If LCase(strLeftString) = LCase(strKey) Then 
         ReadIni = Trim(Mid(strLine, intEqualPos + 1)) 
         ' In case the item exists but value is blank 
         If ReadIni = "" Then 
          ReadIni = " " 
         End If 
         ' Abort loop when item is found 
         Exit Do 
        End If 
       End If 

       ' Abort if the end of the INI file is reached 
       If objIniFile.AtEndOfStream Then Exit Do 

       ' Continue with next line 
       strLine = Trim(objIniFile.ReadLine) 
      Loop 
     Exit Do 
     End If 
    Loop 
    objIniFile.Close 
Else 
    WScript.Echo strFilePath & " doesn't exists. Exiting..." 
    Wscript.Quit 1 
End If 

Ende Funktion

Answer 3

Hier gehen Sie, dieser Code wird die Schleife durchführen. Das Problem, das Sie hatten, bestand darin, die readline für den gleichen Stream wiederzuverwenden, und es wurde nach dem EOF (und/oder) nach dem Erstellen einer Dateisperrenkonkurrenz gesucht.

Const TristateFalse = 0 
Const ForReading = 1 

strINIfile = "c:\scripts\testconfig.ini" 
strSection = "[Section2]" 
strItem = "param3" 

Set objFSO = WScript.CreateObject("Scripting.Filesystemobject") 
Set objINIstream = objFSO.OpenTextFile(strINIfile, ForReading, False, TristateFalse) 

boolCheckSection = False 

Do While Not objINIstream.AtEndOfStream 
    strLine = Trim(objINIstream.ReadLine) 

    ' Determine if we're in the section, set boolcheck if so 
    If InStr(UCase(strLine),UCase(strSection)) Then  
     boolCheckSection = True  
    ElseIf InStr(UCase(strLine), "[") Then 
     boolCheckSection = False 
    End If 

    ' If so, read the proper value and store in variable 
    If boolCheckSection Then 
     If InStr(UCase(strLine), UCase(strItem)) Then 
      tmpParam = Split(strLine, "=") 
      strParamValue = Trim(tmpParam(1)) 
      Exit Do ' exit loop with set variable 
     End If  
    End If 

Loop 

WScript.Echo strParamValue 

Answer 4

Vielen Dank an alle für Ihre Antworten. Wenn ich meine vorgeschlagenen Codes ansehe und sie studiere, merke ich, dass an meinem eigenen Code überhaupt nichts falsch ist (obwohl es 2 while-Schleifen gab, hat es sie richtig verlassen). Nachdem ich Ihre vorgeschlagenen Codes getestet hatte, stellte ich fest, dass es zufällig in meinen Testfällen bestätigt wurde und nachdem ich darüber nachgedacht hatte, erkannte ich, dass die Hauptanwendung, auf die ich testet, immer noch auf diese Datei zugreift (obwohl ich nicht weiß, wofür).

Die Lösung, die ich fand, war eine, die wir immer vorschlagen, wenn wir manuell testen; Kopiere das Original und arbeite an der Kopie.

Auch, danke für Ihre vorgeschlagenen Codes, gaben sie mir verschiedene Blickwinkel, um meine Code-Design und Lesbarkeit zu verbessern.