Power-Point 2013 Export zu Latex mit pdfcrop

Question

Ich habe eine Powerpoint-Präsentation mit ~ 100 Folien.

Jede Folie hat eine Figur. Ich bearbeite jede Folie [arbeite an jeder Figur] und speichere dann jede Folie einzeln im PDF-Format.

Ich schneide jedes pdf getrennt in Adobe Acrobat, um Leerraum und einige andere Diaelemente zu entfernen, die ich in der endgültigen Zahl nicht gehen möchte. Dann füge ich dieses pdf in Texmaker als eine Abbildung für mein Latexdokument ein. Dieser Prozess ist sehr ineffizient.

Bitte schlagen Sie einige Möglichkeiten vor, wie ich diesen Prozess teilweise oder vollständig automatisieren kann.

Ich habe versucht, Makro in Powerpoint zu automatisieren mindestens speichern die aktuelle Folie als PDF-Teil, aber es öffnet ein Vba-Fenster beim Klicken definieren Makro über Entwickler Registerkarte und ich habe keine Kenntnisse von VBA-Skripting.

Danke.

Answer 1

Gibt es einen Grund für den Export als PDF anstelle eines Rasterformats wie JPG oder PNG? Es gibt einige Open-Source-Lösungen, die von VBA aufgerufen werden können, um diese Bildformate zu beschneiden. Wenn Sie PDF benötigen, dann wird dieses Makro tun, was Sie brauchen:

Option Explicit 

' ********************************************************* 
' Purpose : PowerPoint VBA macro to export slides as either 
'   and image or a PDF. 
' Author : Jamie Garroch from htpp://youpresent.co.uk/ 
' Date : 17MAY2016 
' ********************************************************* 
Sub ExportEachSlidesAsPDF() 
    Const myPath = "C:\Temp\" 
    Dim oSld As Slide 
    For Each oSld In ActivePresentation.Slides 
    ' The next commented line exports the slide as a JPG 
    'oSld.Export myPath & ActivePresentation.Name & " Slide " & oSld.SlideIndex & ".jpg", "JPG" 

    ' Export each slide as a PDF 
    With ActivePresentation 
     .PrintOptions.Ranges.ClearAll 
     .PrintOptions.Ranges.Add oSld.SlideIndex, oSld.SlideIndex 
     .ExportAsFixedFormat2 Path:=myPath & ActivePresentation.Name & " Slide " & oSld.SlideIndex & ".pdf", _ 
     FixedFormatType:=ppFixedFormatTypePDF, _ 
     Intent:=ppFixedFormatIntentPrint, _ 
     FrameSlides:=msoFalse, _ 
     HandoutOrder:=ppPrintHandoutHorizontalFirst, _ 
     OutputType:=ppPrintOutputSlides, _ 
     PrintHiddenSlides:=msoFalse, _ 
     PrintRange:=.PrintOptions.Ranges(1), _ 
     RangeType:=ppPrintSlideRange 
    End With 
    Next 
End Sub