Erstellungsskriptfehler, nicht unterstützte Gradle DSL-Methode gefunden: 'signingConfig()'

Question

Ich versuche, Gradle einzurichten, um eine Google Play Store-Version in Android Studio 0.4.5 zu erstellen. In den Einstellungen verwende ich den Standard-Wrapper. Ich habe das Dialogfeld "Projekteigenschaften" verwendet, um den Signaturtyp "config" und den Buildtyp "release" einzurichten. Ich habe nur ein Build-Modul. Hier ist die build.gradle-Datei, die in Folge:

apply plugin: 'android' 

android { 
    compileSdkVersion 19 
    buildToolsVersion '19.0.1' 
    defaultConfig { 
     minSdkVersion 15 
     targetSdkVersion 19 
     versionCode 10 
     versionName "1.0" 
    } 
    buildTypes { 
     release { 
      runProguard true 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt' 
      debuggable false 
      signingConfig playstore 
      proguardFile 'proguard-rules.txt' 
     } 
    } 
    signingConfigs { 
      playstore { 
      keyAlias 'mykeyalias' 
      storeFile file('playstore.jks') 
      keyPassword 'xxxxx' 
      storePassword 'xxxxx' 
     } 
    } 
} 

dependencies { 
    compile fileTree(dir: 'libs', include: ['*.jar', '*.aar']) 
    compile 'com.android.support:support-v4:+' 
    compile files('libs/libGoogleAnalyticsServices.jar') 
} 

Aber ich erhalte die folgende Fehlermeldung, wenn gradle zu synchronisieren versucht:

Build script error, unsupported Gradle DSL method found: 'signingConfig()'! 
      Possible causes could be: 
      - you are using Gradle version where the method is absent 
      - you didn't apply Gradle plugin which provides the method 
      - or there is a mistake in a build script 

Gibt es etwas, ich brauche die richtige gradle Setup zu tun?

Vielen Dank im Voraus.

Answer 1

Zuerst definieren Sie Ihre SigningConfigs vor Ihrem buildTypes Block. Auch playstore Methode ist innerhalb signingConfigs so müssen Sie eine Referenz in einer Art wie signingConfigs.playstore geben.

Ihre letzte build.gradle Datei soll wie folgt aussehen:

apply plugin: 'android' 

android { 
    compileSdkVersion 19 
    buildToolsVersion '19.0.1' 
    defaultConfig { 
     minSdkVersion 15 
     targetSdkVersion 19 
     versionCode 10 
     versionName "1.0" 
    } 

    signingConfigs { 
      playstore { 
       keyAlias 'mykeyalias' 
       storeFile file('playstore.jks') 
       keyPassword 'xxxxx' 
       storePassword 'xxxxx' 
     } 
    } 


    buildTypes { 
     release { 
      runProguard true 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt' 
      debuggable false 
      signingConfig signingConfigs.playstore 
      proguardFile 'proguard-rules.txt' 
     } 
    } 

} 

dependencies { 
    compile fileTree(dir: 'libs', include: ['*.jar', '*.aar']) 
    compile 'com.android.support:support-v4:+' 
    compile files('libs/libGoogleAnalyticsServices.jar') 
}